GO BACK

AppleScript Studio教室　その7

「より本格的なアプリへ」

■ドロワーを使ってみよう！

　さて、AppleScript Studioを使ってごく簡単なアプリが作れることはわかってきました。今回は、もうちょっと難しそうなアプリを作ってみましょう。そのためには、もう少し複雑なインターフェイスの使い方を覚えておく必要もあります。

　まずは、「ドロワー」の利用から考えていきましょう。ドロワーというのはMac OS Xからサポートされたインターフェイスで、ウィンドウの横に引き出しのようにくっついて出てくる、アレのことです。Mailやその他さまざまなアプリで使われていますね。せっかくアプリ作りに挑戦するなら、「いかにもMac OS X用」といったものを作りたいものです。ドロワーは、「これぞXのためのもの」という感じがしますね。

1. まずInterface Builderでnibファイル（MainMenu.nib）を開き、パレットのCocoa Windowsアイコンを選択します。
2. そこにあるNSDrawer部品（右下のDrawerと書いてるやつ）を、Nibファイルウィンドウの「Instances」タブのエリア内にドラッグ＆ドロップします。（デザインウィンドウではないよ！）すると、「NSDrawer」と表示されたアイコンが追加されます。
3. 次に、ドロワーの中に表示する部品として「NSView」を用意します。Cocoa Container Viewsアイコンを選択し、その中にあるNSView部品（Custom Viewと書いてあるやつ）を、やっぱりNibファイルウィンドウの「Instances」タブのエリア内にドラッグ＆ドロップします。これで、「View」と表示されたアイコンが追加されます。
4. 作成したNSDrawerに、「Parent Window」というものを設定します。これは、ドロワーが取り付けられるウィンドウを示すものです。作業の手順は以下のようになります。
1. Nibファイルウィンドウの「Instances」タブ内にあるNSDrawerアイコンから、Ctrlキーを押したまま、同じ「Instances」タブ内にあるWindowアイコンまでドラッグ＆ドロップしましょう。
2. 薄紫色の線が延びて２つのアイコンがつながり、Infoウィンドウの「Connections」という表示に切り替わります。
3. ここで「Outletes」という部分にある「parentWindow」という項目を選択して、下の「Connect」ボタンを押して下さい。これで、つなげたWindowアイコンの部品が、NSDrawerのParent windowに接続されます。
5. 続いて、NSDrawerに「Current View」というものを設定します。これは、ドロワーに表示する部品を示すものです。——やはりNibファイルウィンドウの「Instances」タブ内にあるNSDrawerアイコンから、Ctrlキーを押したままViewアイコン（先ほど作ったNSViewね）までドラッグ＆ドロップします。そしてInfoウィンドウの「Connections」にある「currentView」項目を選択して「Connect」ボタンを押せば、接続完了です。
   

■NSTableViewについて

1. まず、デザインウィンドウに配置したNSTableViewを選択します。注意したいのは、外側のNSScrollViewではなく、内部のNSTableViewを選択する、ということです。すなわち、配置してある部品をクリックした後、ダブルクリックして内側の部品を選択しておきます。
2. このNSTableViewから、Nibファイルウィンドウの「Instances」タブ内にある「ASKDataSource」アイコンまで、Ctrlキーを押したままドラッグ＆ドロップをします。
3. Infoウィンドウの表示が「Connections」に切り替わるので、その「Outlets」内にある「dataSource」という項目を選択し、「Connect」ボタンを押します。これで、NSTableViewのデータとしてASKDataSourceが設定されます。
   

■マニュアルブラウザを作る

NSTextField
・Send Actionアトリビュート：Only On Enterを選択
・「AppleScript」のName：text1
・「AppleScript」のAction/actionイベントをON
・「AppleScript」のスクリプトファイル（○○.applescript）をON

NSButton
・Nameアトリビュート：List
・「AppleScript」のName：listbtn
・「AppleScript」のAction/clickedイベントをON
・「AppleScript」のスクリプトファイルをON

NSScrollView（NSTextViewの外側のやつ）
・「AppleScript」のName：scroll1

NSTextView（NSTextView本体）
・「AppleScript」のName：textview1

NSView
・「AppleScript」のName：view1

NSScrollView（NSTableViewの外側）
・「AppleScript」のName：listscroll

NSTableView
・Allows Empty SelectionアトリビュートをON
・Allows Multiple SelectionアトリビュートをOFF
・Allows Column SelectionアトリビュートをOFF
・OptionエリアのColmsを「１」にする（これで１列の表示になる）
・「AppleScriptのName：listtable
・「AppleScript」のAction/clickedをON
・「AppleScript」のスクリプトファイルをON

NSTableColumn（NSTableViewの１列目のカラム）
・Column titleアトリビュート：command list
・OptionsエリアのEditableとResizableをそれぞれOFF
・Identifierアトリビュート：listcolumn

property flg : false

on clicked theObject
	if name of theObject is "listbtn" then
		tggleDrawer()
	else if name of theObject is "listtable" then
		putList()
	end if
end clicked

on tggleDrawer()
	tell drawer "drawer1" of window "win1"
		if flg is false then
			open drawer
		else
			close drawer
		end if
		set flg to not flg
	end tell
end tggleDrawer

on putList()
	tell table view "listtable" of scroll view "listscroll" of content view of 〜
			drawer "drawer1" of window "win1"
		set n to clicked row
	end tell
	if n = 0 then
		set str1 to ""
	else
		tell data source of table view "listtable" of scroll view "listscroll" of 〜
				content view of drawer "drawer1" of window "win1"
			set str1 to contents of data cell "listcolumn" of data row n
		end tell
	end if
	set contents of text field "text1" of window "win1" to str1
	doMan()
end putList

on action theObject
	if name of theObject is "text1" then
		doMan()
	end if
end action

on will finish launching theObject
	tell data source of table view "listtable" of scroll view "listscroll" of 〜
			content view of drawer "drawer1" of window "win1"
		make new data column at the end of the data columns 〜
				with properties {name:"listcolumn"}
	end tell
end will finish launching

on doMan()
	tell window "win1"
		set str1 to string value of text field "text1"
		try
			do shell script "man" & space & str1
			set ans to result
		on error
			set ans to "not found manual."
		end try
		set contents of text view "textview1" of scroll view "scroll1" to ans
	end tell
	tell data source of table view "listtable" of scroll view "listscroll" of 〜
			content view of drawer "drawer1" of window "win1"
		make new data row at the end of the data rows
		set n to data rows count
		set contents of data cell "listcolumn" of data row n to str1
	end tell
	tell table view "listtable" of scroll view "listscroll" of content view of 〜
			drawer "drawer1" of window "win1"
		update
	end tell
end doMan

■NSTableViewのデータ利用

tell data source of table view "listtable" of scroll view "listscroll" of 〜
		content view of drawer "drawer1" of window "win1"
	make new data column at the end of the data columns with properties {name:"listcolumn"}
end tell

make new data column at the end of the data columns of 《data source》[with properties { 属性 } ]

tell data source of table view "listtable" of scroll view "listscroll" of 〜
		content view of drawer "drawer1" of window "win1"
	make new data row at the end of the data rows
	set n to data rows count
	set contents of data cell "listcolumn" of data row n to str1
end tell

contents of data cell 名前/番号 of data row 名前/番号 of 《data source》

　NSTableViewは、データを使いこなそうとするといろいろと難しいのですが、とりあえず「data sourceにdata columnとdata rowを組み込んで操作する」という基本さえわかれば、一応簡単な操作ぐらいはできるようになります。これは複雑なコントロールなので、焦らず基本からじっくりとマスターしていきましょう。

GO NEXT