// Party Time scripts
// Copyright © 1997 by Apple Computer, Inc.  All rights reserved.

installscript := func(pf, removeFrame) begin
	local t:=GetLayout("Party Time Slip");	// this is the view template used below
	
	if GetRoot().calendar then
		GetRoot().calendar:RegMeetingType(kAppSymbol, 
			{item:		"Party", 
			icon: 		t.bigicon, 
			smallicon:	t.smallicon,
			NewMeeting: func(date, parentBox) begin
				// Use the Dates API to create the new meeting soup entry.
				// Default to starting at the current time and going for 2 hours (120 minutes)
				local soupEntry := getroot().calendar:AddAppointment("", date, 120, nil, nil);

				// say that it's our special type of meeting
				soupEntry.meetingType := kAppSymbol;
				
				// provide defaults for the slip's checkboxes
				soupEntry.drinkArr := [true, true, nil, nil];
				soupEntry.foodArr :=  [true, true, true, nil];
				
				// open the slip
				local theView := {_proto: t, soupEntry: soupEntry};
				GetRoot().calendar:RememberedOpen(BuildContext(theView));
				nil;
			  end,
			OpenMeeting: func(soupEntry, date, parentBox) begin
				local theView := {_proto: t, soupEntry: soupEntry};
				GetRoot().calendar:RememberedOpen(BuildContext(theView));
				nil;
			  end,
		  });
end;

RemoveScript:=func(removeFrame) begin
	if GetRoot().calendar then
		GetRoot().calendar:UnRegMeetingType(kAppSymbol);
end;